[xml-tech] Re: parametre perdu

Bonjour Julien,

J'avais eu une problematique similaire en voulant diviser l'ensemble des
fils d'un élément par groupes de 3 (pour les présenter dans une table),
mon approche se base sur l'association d'une clé aux elements qui
contient la valeur de la division entière de la position de l'élément
parmi ses frères :

avec le xml source :
<row>
  <item>item1</item>
  <item>item2</item>
  <item>item3</item>
  <item>item4</item>
  <item>item5</item>
  <item>item6</item>
  <item>item7</item>
  </row>

J'obtiens :
<rowgroup>
  <group
card="3"><item>item1</item><item>item2</item><item>item3</item></group>
  <group
card="3"><item>item4</item><item>item5</item><item>item6</item></group>
  <group card="1"><item>item7</item></group>
  </rowgroup>

Cela me semble assez proche de votre probleme, voici le xslt :

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  <xsl:output method="xml" encoding="utf-8" indent="yes"/>

  <xsl:key name="modulo" match="item"
use="floor(count(preceding-sibling::item) div 3)"/>

  <xsl:template match="row">
    <rowgroup>
      <xsl:apply-templates/>
    </rowgroup>
  </xsl:template>

  <xsl:template match="item[count(preceding-sibling::item) mod 3 = 0]">
    <group
card="{count(key('modulo',floor(count(preceding-sibling::item) div 3)))}">
      <xsl:apply-templates
select="key('modulo',floor(count(preceding-sibling::item) div 3))"
mode='items'/>
    </group>
  </xsl:template>

 <xsl:template match="item"/>

  <xsl:template match="item" mode="items">
    <item><xsl:value-of select="."/></item>
  </xsl:template>

</xsl:stylesheet>

En espérant que cela puisse vous aider...
Stéphane.

julien TOUCHE wrote:

>Herve AGNOUX wrote on 25/04/2006 00:21:
>
>
>>Et si vous écriviez "$cur_image/path" ?...
>>
>>
>ah, je me disais bien que ca devait être bête ...
>merci à tous les 2.
>
>par contre, dans la suite, j'obtiens:
>
>**3 treating1 </path/to/1.jpg>.
>**3 Getting </path/to/1.jpg>. (position 0)
>**3 treating2 </path/to/2.jpg>.
>**3 Getting </path/to/2.jpg>. (position 1)
>**3 treating3 </path/to/3.jpg>.
>**3 Getting </path/to/3.jpg>. (position 2)
>**3 treating4 </path/to/4.jpg>.
>**3 treating1 </path/to/4.jpg>.
>**3 Getting </path/to/4.jpg>. (position 0)
>**3 treating2 <>. <= les problèmes commencent
>**1 Getting <>.
>**3 treating3 <>.
>**1 Getting <>.
>
>
>avec le code recursif (puisque les modifications de variables marchent
>pas) suivant:
>
>le début est le code précédent avec un '$' en plus, la phase 4 étant:
>
> <xsl:message>**3 treating4 &lt;<xsl:value-of
>select="$image[4]/path"/>&gt;.</xsl:message>
> <xsl:choose>
> <xsl:when test="$image[4]/note &lt; 3">
> <xsl:call-template name="p3parPage">
> <xsl:with-param name="image" select="$image[4]"/>
> <xsl:with-param name="positionPage" select="0"/>
> </xsl:call-template>
> </xsl:when>
> <xsl:otherwise>
> <xsl:call-template name="p1parPage">
> <xsl:with-param name="image" select="$image[4]"/>
> <xsl:with-param name="positionPage" select="0"/>
> </xsl:call-template>
> </xsl:otherwise>
> </xsl:choose>
>
>normalement on rentre dans p3parPage (auquel appartient le bout de code
>ci-dessus)
>
> <xsl:template name="p3parPage">
> <xsl:param name="image" select="error"/>
> <xsl:param name="positionPage" select="error"/>
>
> <xsl:copy-of select="$header" />
>
> <xsl:message>**3 treating1 &lt;<xsl:value-of
>select="$image/path"/>&gt;.</xsl:message>
> <xsl:call-template name="Affiche1photoSur3">
> <xsl:with-param name="cur_image" select="$image"/>
> <xsl:with-param name="positionPage" select="0"/>
> </xsl:call-template>
>
> <xsl:message>**3 treating2 &lt;<xsl:value-of
>select="$image[2]/path"/>&gt;.</xsl:message>
> <xsl:choose>
> <xsl:when test="$image[2]/note &lt; 3">
> <xsl:call-template name="Affiche1photoSur3">
> <xsl:with-param name="cur_image" select="$image[2]"/>
> <xsl:with-param name="positionPage" select="1"/>
> </xsl:call-template>
> </xsl:when>
> <xsl:otherwise>
> <xsl:copy-of select="$footer" />
> <xsl:call-template name="p1parPage">
> <xsl:with-param name="image" select="$image[2]"/>
> <xsl:with-param name="positionPage" select="0"/>
> </xsl:call-template>
> </xsl:otherwise>
> </xsl:choose>
>
>[...]
>
>
>normalement sur le premier appel, le passage des variables est bon, mais
>sur le
>second passage, on ne recupere que la premiere ...
>
>idées ?
>
>
>merci
>@+
>
>
>
>
>--
>Devenez redacteur <XML>fr et contribuez au developpement du
>xml francophone (http://xmlfr.org/infos/redacteurs/) !
>
>Liste de diffusion "xml-tech@xmlfr.org" (http://xmlfr.org).
>
>Cette liste est a votre disposition pour discuter en francais de
>tout sujet technique lie a XML.
>
>Pour resilier votre abonnement, envoyez un message contenant
>la commande "unsubscribe" a xml-tech-request@xmlfr.org
>(mailto:xml-tech-request@xmlfr.org?Subject=unsubscribe)
>
>---------------------------------------------------------------------------------------
>Wanadoo vous informe que cet e-mail a ete controle par l'anti-virus mail.
>Aucun virus connu a ce jour par nos services n'a ete detecte.
>
>
>
>

-- 
   Stéphane Bonhomme           --           Exselt Services
Formations, Conseil et Réalisations en Ingénierie Documentaire,
            Technologies Web et Logiciels Libres
     s.bonhomme@wanadoo.fr   -   http://www.exselt.com
        04 76 17 09 40        /      06 88 57 27 08 
--
Devenez redacteur <XML>fr et contribuez au developpement du
xml francophone (http://xmlfr.org/infos/redacteurs/) !
Liste de diffusion "xml-tech@xmlfr.org" (http://xmlfr.org).
Cette liste est a votre disposition pour discuter en francais de 
tout sujet technique lie a XML.
Pour resilier votre abonnement, envoyez un message contenant 
la commande "unsubscribe" a xml-tech-request@xmlfr.org
(mailto:xml-tech-request@xmlfr.org?Subject=unsubscribe)