[xml-tech] Re: [XSL] Aplatir un élément qui contient des élément imbriqués

On Tue, Nov 29, 2005 at 09:56:13PM +0100,
 Stephane Bortzmeyer <stephane@sources.org> wrote
 a message of 39 lines which said:

> Ah oui, tr?s bien, ?a marche, bravo et merci beaucoup.

Ecartis cherche à m'énerver, on dirait. Lorsqu'il se permet de virer
des attachements, il massacre les accents :-(

> -- Binary/unsupported file stripped by Ecartis --
> -- Type: application/xml

Sur une liste XML, un logiciel qui dit que XML est du binaire, c'est
fort :-)

Voici donc les fichiers dans le corps du message.

****************************

<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version='1.0'>

  <xsl:template match="para" name="para.block">
    <xsl:param name="index" select="0"/>
    <xsl:variable name="nbBlocks" select="count(code|enum)"/>
      <p>
        <xsl:apply-templates
          select="node()[((count(preceding-sibling::code) +
                  count(preceding-sibling::enum)) = $index) and
                  (not(self::code) and not(self::enum))]"/>
      </p>
    <xsl:apply-templates select="enum[$index + 1]"/>
    <xsl:apply-templates select="code[$index + 1]"/>
    <xsl:if test="$index &lt; $nbBlocks">
      <xsl:call-template name="para.block">
        <xsl:with-param name="index" select="$index + 1"/>
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

  <xsl:template match="code">
    <pre>
      <xsl:apply-templates/>
    </pre>
  </xsl:template>

  <xsl:template match="enum">
    <ul>
      <xsl:apply-templates/>
    </ul>
  </xsl:template>

  <xsl:template match="item">
    <li>
      <xsl:apply-templates/>
    </li>
  </xsl:template>

</xsl:stylesheet>

*************************************

<blog>
<para>Ce code :
<code>
printf("Hello\n");
</code>
fait ca tres bien.<code>rm</code></para>
<para>Et cet autre para ?</para>
<para>Ce troisieme a une enumeration :
<enum>
<item>Un</item>
<item>Deux</item>
</enum></para>

</blog>

--
Devenez redacteur <XML>fr et contribuez au developpement du
xml francophone (http://xmlfr.org/infos/redacteurs/) !
Liste de diffusion "xml-tech@xmlfr.org" (http://xmlfr.org).
Cette liste est a votre disposition pour discuter en francais de 
tout sujet technique lie a XML.
Pour resilier votre abonnement, envoyez un message contenant 
la commande "unsubscribe" a xml-tech-request@xmlfr.org
(mailto:xml-tech-request@xmlfr.org?Subject=unsubscribe)