<xsl:if
test="not(substring(nom,1,1)=substring(preceding::adherent[1]/nom,1,1))">
le probleme etait que substring(preceding::node()/nom,1,1)) convertit
preceding::node()/nom de type nodeset en texte, le processeur prends
donc le contenu du premier noeud du nodeset dans l'ordre du document.
Qui est toujours le premier adhérent de votre fichier.
si l'on écrit preceding::adherent[1]
le nodeset est réduit au seul premier noeud de preceding::adherent, qui
est un nodeset dont les elements sont ordonnés (hé oui les nodeset ont
un ordre, ce ne sont pas des ensembles !) dans l'ordre ou ils sont
rencontrés lors du parcours de l'axe spéficié, le premier est donc le
premier noeud précédent le noeud courant dans l'ordre du document !!!!
Ce qui veux dire que cette solution ne fonctionne pas si les adhérents
ne sont pas classés par ordre alphabétique dans le doc source !
Pour cela, je vous propose d'utiliser xsl:key :
<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html"/>
<xsl:key name="lettre" match="/adherents/adherent"
use="substring(nom,1,1)"/>
<xsl:template match="/">
<html>
<head>
<title>liste des adhérents</title>
</head>
<body>
<xsl:apply-templates select="adherents/adherent">
<xsl:sort select="nom" order="ascending" />
</xsl:apply-templates>
</body>
</html>
</xsl:template>
<xsl:template match="adherent"/>
<xsl:template
match="adherent[not(preceding::adherent[substring(nom,1,1)=substring(current()/nom,1,1)])]">
<xsl:value-of select="substring(nom,1,1)" />
<br />
<xsl:for-each select="key('lettre',substring(current()/nom,1,1))">
<xsl:sort select="nom" order="ascending" />
<!-- tri par rapport au nom -->
<xsl:value-of select="nom" />
<xsl:text> - </xsl:text>
<xsl:value-of select="prenom" />
<br />
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
mes 2¢
Stéphane.
Le mercredi 30 mars 2005 à 12:04 +0200, Patrice Harmegnies a écrit :
> Voilà j'ai un fichier xml avec un n½ud racine adhérents
> Ce n½ud contient plusieurs n½uds adherent qui lui-même contient les n½uds
> nom et prenom
> Je veux faire un genre de glossaire avec affichage de la première lettre du
> nom si différente
>
> Voici mon template
> <?xml version="1.0" encoding="iso-8859-1"?>
> <xsl:stylesheet version="1.0"
> xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
> <xsl:output method="html"/>
> <xsl:template match="/">
> <html>
> <head><title>liste des adhérents</title>
> </head>
> <body>
> <xsl:for-each select="adherents/adherent">
> <xsl:sort select="nom" order="ascending" />
> <!-- tri par rapport au nom -->
> <xsl:if test ="not(substring(self::node()/nom,1,1) =
> substring(preceding::node()/nom,1,1))">
> <xsl:value-of select="substring(self::node()/nom,1,1)" />
> <br />
> </xsl:if>
> <xsl:value-of select="self::node()/nom" />
> <xsl:text> - </xsl:text>
> <xsl:value-of select="self::node()/prenom" />
> <br />
> </xsl:for-each>
> </body>
> </html>
> </xsl:template>
> </xsl:stylesheet>
>
> Voici ce que j'obtiens
> B
> Bart - Paul
> Bart - Jean
> D
> Dumaret - Annie
> D
> Durand - Maggie
> P
> Poulain - Sophie
>
> Normalement, le deuxième D ne devrait pas s'afficher ??
> Vous avez une idée ..
>
> P. Harmegnies
> patrice.harmegnies@skynet.be
>
>
> --
> Devenez redacteur <XML>fr et contribuez au developpement du
> xml francophone (http://xmlfr.org/infos/redacteurs/) !
>
> Liste de diffusion "xml-tech@xmlfr.org" (http://xmlfr.org).
>
> Cette liste est a votre disposition pour discuter en francais de
> tout sujet technique lie a XML.
>
> Pour resilier votre abonnement, envoyez un message contenant
> la commande "unsubscribe" a xml-tech-request@xmlfr.org
> (mailto:xml-tech-request@xmlfr.org?Subject=unsubscribe)
>
>
--
Stéphane Bonhomme -- Exselt Services
Formations, Conseil et Réalisations en Ingénierie Documentaire,
Technologies Web et Logiciels Libres
s.bonhomme@wanadoo.fr - http://www.exselt.com
04 76 17 09 40 / 06 88 57 27 08
--
Devenez redacteur <XML>fr et contribuez au developpement du
xml francophone (http://xmlfr.org/infos/redacteurs/) !
Liste de diffusion "xml-tech@xmlfr.org" (http://xmlfr.org).
Cette liste est a votre disposition pour discuter en francais de
tout sujet technique lie a XML.
Pour resilier votre abonnement, envoyez un message contenant
la commande "unsubscribe" a xml-tech-request@xmlfr.org
(mailto:xml-tech-request@xmlfr.org?Subject=unsubscribe)
Received on Wed Mar 30 22:59:42 2005
