[xml-tech] Re: <xsl:copy-of select= ? />

Le mardi 01 février 2005 à 12:42 +0100, Eric van der Vlist a écrit :

> Pour faire les deux la fois, une solution serait de parcourir le
> contenu de l'lment texte en "pas pas" au moyen de l'axe
> "following-sibling", de recopier les noeuds tant que la longueur n'est
> pas atteinte, de tronquer le premier qui fasse dpasser cette longueur
> puis de s'arrter.

Je me demande si cela ne fait pas partie des choses qui sont plus
faciles à faire qu'à expliquer :-) ...

La transformation suivante (à adapter) implémente cela :

++++++++++++++++++++++++++++++++++++++++++++
<?xml version="1.0" encoding="utf-8"?>

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:output indent="yes"/>

<xsl:param name="lMaxParDefaut">65</xsl:param>

<xsl:template match="/">
  <res>
    <xsl:apply-templates select="/*/texte/node()[1]" mode="tronque"/>
  </res>
</xsl:template>

<xsl:template match="text()" mode="tronque">
        <xsl:param name="lMax" select="$lMaxParDefaut"/>
        <xsl:param name="l" select="0"/>
        <xsl:choose>
                <xsl:when test="$l + string-length(.) &lt; $lMax">
                        <xsl:copy/>
                        <xsl:apply-templates select="following-sibling::node()[1]" mode="tronque">
                                <xsl:with-param name="lMax" select="$lMax"/>
                                <xsl:with-param name="l" select="$l + string-length(.)"/>
                        </xsl:apply-templates>
                </xsl:when>
                <xsl:otherwise>
                        <xsl:value-of select="substring(., 1, $lMax -$l )"/>
                </xsl:otherwise>
        </xsl:choose>
</xsl:template>

<xsl:template match="*" mode="tronque">
        <xsl:param name="lMax" select="$lMaxParDefaut"/>
        <xsl:param name="l" select="0"/>
        <xsl:copy>
                <xsl:copy-of select="@*"/>
                <xsl:apply-templates select="node()[1]" mode="tronque">
                        <xsl:with-param name="lMax" select="$lMax"/>
                        <xsl:with-param name="l" select="$l"/>
                </xsl:apply-templates>
        </xsl:copy>
        <xsl:if test="$l + string-length(.) &lt; $lMax">
                <xsl:apply-templates select="following-sibling::node()[1]" mode="tronque">
                        <xsl:with-param name="lMax" select="$lMax"/>
                        <xsl:with-param name="l" select="$l + string-length(.)"/>
                </xsl:apply-templates>
        </xsl:if>
</xsl:template>

</xsl:transform>
++++++++++++++++++++++++++++++++++++++++++++

Elle se base sur les caractères physiquement présents (deux espaces
consécutifs comptent pour deux caractères) et non sur la taille
"affichée" (ce qui la compliquerait pas mal).

Cordialement,

Eric van der Vlist

-- 
Don't you think all these XML schema languages should work together?
                                                         http://dsdl.org
------------------------------------------------------------------------
Eric van der Vlist       http://xmlfr.org            http://dyomedea.com
(ISO) RELAX NG   ISBN:0-596-00421-4 http://oreilly.com/catalog/relax
(W3C) XML Schema ISBN:0-596-00252-1 http://oreilly.com/catalog/xmlschema
------------------------------------------------------------------------
--
Devenez redacteur <XML>fr et contribuez au developpement du
xml francophone (http://xmlfr.org/infos/redacteurs/) !
Liste de diffusion "xml-tech@xmlfr.org" (http://xmlfr.org).
Cette liste est a votre disposition pour discuter en francais de 
tout sujet technique lie a XML.
Pour resilier votre abonnement, envoyez un message contenant 
la commande "unsubscribe" a xml-tech-request@xmlfr.org
(mailto:xml-tech-request@xmlfr.org?Subject=unsubscribe)