From: Pierre Attar (patt@tireme.fr)
Date: 10/05/2001 - 10:08
>
>Avec XMLSpy, je suis capable de générer de la documentation qui n'est pas
>si mal. Le problème est qu'ils décident de classer tout selon un bête
>ordre alphabetique qui n'a que peu d'intérêt quand on lit le papier pour
>comprendre le modèle. J'ai essayé de voir avec eux s'ils proposaient autre
>chose ou s'ils avaient d'autres idées pour la prochaine version ... rien
>du tout.
En attendant de trouver mieux, voici la feuille de style XSLT que j'ai
réalisé pour tout réordonner ce que génère XMLSpy.
En toute logique, ca marche avec n'importe quel outil XSLT selon le
principe suivant :
- le fichier d'entrée est celui issu de XMLSpy (il faut
lui ajouter un doctype pour déclarer l'entité nbsp
- il faut passer un paramètre dénommé 'schemaFile' et
contenant l'url du fichier Schema
Le tout réorganise le fichier d'entrée selon l'ordre du schéma. Je suis sûr
que ce n'est pas parfait et que cela peu être amélioré. A vous de voir.
Pierre
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsd="http://www.w3.org/2000/10/XMLSchema"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<!-- mode d'emploi :
- fileIn : le fichier issu de XMLSpy
- param schemaFile : le fichier Schema
génère une doc selon l'ordre du schéma
-->
<xsl:param name="schemaFile"/>
<xsl:output method="html" indent="no"/>
<xsl:key name="spyNames" match="body/a"
use="substring-before(substring-after(./@name,'_'),'_Link')"/>
<xsl:template match="/">
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="html">
<html>
<head>
<xsl:apply-templates select="./head/*"/>
<style type="text/css"> h1 { font-family:
Arial; font-size: 14pt; font-weight: bold; color: #000000;}</style>
</head>
<body>
<xsl:apply-templates select="./body/*[1]"
mode="pas"/>
<xsl:apply-templates
select="document($schemaFile)/xsd:schema/child::*" mode="schema">
<xsl:with-param name="topNode"
select="."/>
</xsl:apply-templates>
</body>
</html>
</xsl:template>
<xsl:template match="xsd:annotation" mode="schema">
<h1>
<xsl:apply-templates select="xsd:documentation"/>
</h1>
</xsl:template>
<xsl:template
match="xsd:element|xsd:simpleType|xsd:complexType|xsd:group|xsd:attributeGroup"
mode="schema">
<xsl:param name="topNode"/>
<xsl:variable name="name" select="./@name"/>
<xsl:apply-templates
select="$topNode/body/a[substring-before(substring-after(./@name,'_'),'_Link')=$name]"
mode="init"/>
</xsl:template>
<xsl:template match="a" mode="init">
<a name="{./@name}"/>
<xsl:apply-templates select="./following-sibling::*[1]"
mode="pas">
<xsl:with-param name="linkName">
<xsl:value-of
select="./following-sibling::span[./@class='elementHeader2'][1]"/>
</xsl:with-param>
</xsl:apply-templates>
</xsl:template>
<xsl:template match="a" mode="pas">
<xsl:param name="linkName"/>
<xsl:variable name="name"
select="./following-sibling::span[./@class='elementHeader2'][1]"/>
<xsl:if test="contains($name,'/')">
<xsl:if test="$linkName=substring-before($name,'/')">
<!-- continuer sinon, arrêter d'avancer -->
<a name="{./@name}"/>
<xsl:apply-templates
select="./following-sibling::*[1]" mode="pas">
<xsl:with-param name="linkName"
select="$linkName"/>
</xsl:apply-templates>
</xsl:if>
</xsl:if>
</xsl:template>
<xsl:template match="*|@*" mode="pas">
<xsl:param name="linkName"/>
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
<xsl:apply-templates select="./following-sibling::*[1]"
mode="pas">
<xsl:with-param name="linkName" select="$linkName"/>
</xsl:apply-templates>
</xsl:template>
<xsl:template match="*|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="*|@*" mode="schema"/>
</xsl:stylesheet>
--
Devenez redacteur <XML>fr et contribuez au developpement du
xml francophone (http://xmlfr.org/infos/redacteurs/) !
Liste de diffusion "xml-tech@xmlfr.org" (http://xmlfr.org).
Cette liste est a votre disposition pour discuter en francais de
tout sujet technique lie a XML.
Pour resilier votre abonnement, envoyez un message contenant
la commande "unsubscribe" a xml-tech-request@xmlfr.org
(mailto:xml-tech-request@xmlfr.org?Subject=unsubscribe)
Archive générée par hypermail 2.1.3 le 28/06/2004 - 11:06 UTC
webmaster@xmlfr.org
| 
